Author
Message This forum is locked: you cannot post, reply to, or edit topics. This topic is locked: you cannot edit posts or make replies.
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

While exploring SirWoot's claim (just to the East of my claim) I found some water that wasn't at sea level. When I walked through it, though, I was unhappily surprised to not hear a darn thing but my own steps on solid ground. So, I thought I'd try to make a water stepping sound script.

Although it clearly needs more work, this thing has been distracting me from the rest of the jungle, so I've finally decided to stop trying to perfect it and give it over to whoever would like to make it better. It should be placed on an activator that uses either a bc_scum mesh or a water mesh from OOT.

I've tried to copy it exactly as I printed it out, so if I did a good job, then copy+pasting it right into a new script should work, though my typing skills have seen better days.

Code:

begin TR_Po_WaterStepSound

;v1.13

short PCStartPosX
short PCStartPosY
short PCPosX
short PCPosY
short Move
short Step
short Sound
float Timer
float Switch
short speed

if ( MenuMode == 1 )
     return
endif

set PCPosX to "player"->GetPos, X
set PCPosY to "player"->GetPos, Y

if ( Sound == 1 )
     if ( Timer < Switch )
          set Timer to Timer + GetSecondsPassed
          return
     else
          set Sound to 0
          set Timer to 0
     endif
endif

if ( GetStandingPC == 1 )

     if ( PCPosX != PCStartPosX )
          set Move to 1
     elseif ( PCPosY != PCStartPosY )
          set Move to 1
     endif

     if ( Move == 1 )

          if ( Step == 1 )
               ;if ( GetSoundPlaying "FootWaterRight" == 0 )
                    PlaySound, "FootWaterLeft"
                    set Step to 0
               ;endif
          else
               ;if ( GetSoundPlaying "FootWaterLeft" == 0 )
                    PlaySound, "FootWaterRight"
                    set Step to 1
               ;endif
          endif

          set Sound to 1
          set Move to 0

     endif ;end move==1

     set PCStartPosX to PCPosX
     set PCStartPosY to PCPosY

     if ( speed != player->GetSpeed )

          if ( player->GetSpeed >= 100 )
               set Switch to 0.375

          elseif ( player->GetSpeed < 35 )
               set Switch to 0.7

          elseif ( player->GetSpeed < 65 )
               set Switch to 0.5

          elseif ( player->GetSpeed < 100 )
               set Switch to 0.45
     
          endif

          set speed to "player"->GetSpeed

     endif

endif ;end StandingPC == 1

end


That should do it. Anyone should feel free to experiment and improve on this....

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Fri Jun 10, 2005 7:40 pm Send private message             Reply with quote                   up  
Abramul
Member
01 Mar 2005



There's a command used in the lava-script to check whether someone is standing on it. Might that be more efficient?
_________________
Tamriel is an impossible place, built on impossible precepts. It's, frankly, a magic ball of sentient schizophrenia. --MK
Post Fri Jun 10, 2005 8:51 pm Send private message             Reply with quote                   up  
Aaron
Developer
11 Sep 2004

Location: My own little world

No Abramal, because his script actually checks if the player is moving, and plays the water-footstep sounds if they are. That's actually a rather clever script and somthing I never thought of. Attaching that to every static water object would be a great way to add some realism to 'fake' water (well, more fake than the other fake water anyway!). The only comment I have is (although I didn't actually check the script for errors) that you should replace GetStandingPC with GetCollidingPC, as if the player is standing through the water, it probubly wouldn't register GetStandingPC, however GetCollidingPC would.
_________________
Claims completed:
Yashazmus, Shrine of Mehrunes Dagon
Mzankh, Dwemer Ruin
Nchazdrumn, Dwemer Ruin
Sirrilas, Shrine of Mephala
Moriken, Abandoned Dunmer Stronghold
Old Necrom Morag Tong GH
Darconis Diamond Mine
Assorted other boring claims.
Post Fri Jun 10, 2005 10:59 pm Send private message       Send e-mail       Reply with quote                   up  
Theo
Developer Emeritus
16 Dec 2004

Location: PRAGUE

What is the variable "Sound" for? From the script it looks like that it is set to 1 whenever sound is played and then timer is activated to reset it to 0. Is it so that the sound is not played in these intervals? Then there should be some condition:
"If Sound == 0" conditioning playing of sound. I don't see any.
Or am I wrong? Did you already tested this script, PoHa?

_________________
THEO
Post Sat Jun 11, 2005 3:00 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

He uses sound to start the timer. However there are a few things I don't know if will work or not. Unfortunitally I don't have my morrowind CD to check. (It's already packed).
Post Sat Jun 11, 2005 3:18 pm Send private message             Reply with quote                   up  
Theo
Developer Emeritus
16 Dec 2004

Location: PRAGUE

Yes, I've observed that as well. But what else does the timer do except reseting sound back to 0 after some time? I think the script should be like this:

begin TR_Po_WaterStepSound
;v1.13

short PCStartPosX
short PCStartPosY
short PCPosX
short PCPosY
short Move
short Step
short Sound
float Timer
float Switch
short speed

if ( MenuMode == 1 )
return
endif

set PCPosX to "player"->GetPos, X
set PCPosY to "player"->GetPos, Y

if ( Sound == 1 )
if ( Timer < Switch )
set Timer to Timer + GetSecondsPassed
return
else
set Sound to 0
set Timer to 0
endif
endif

if ( GetStandingPC == 1 )
if ( PCPosX != PCStartPosX )
set Move to 1
elseif ( PCPosY != PCStartPosY )
set Move to 1
endif
if ( Move == 1 )
if ( Sound == 0 )
if ( Step == 1 )
;if ( GetSoundPlaying "FootWaterRight" == 0 )
PlaySound, "FootWaterLeft"
set Step to 0
;endif
else
;if ( GetSoundPlaying "FootWaterLeft" == 0 )
PlaySound, "FootWaterRight"
set Step to 1
;endif
endif
set Sound to 1
set Move to 0
end if ;end sound==0
endif ;end move==1
set PCStartPosX to PCPosX
set PCStartPosY to PCPosY
if ( speed != player->GetSpeed )
if ( player->GetSpeed >= 100 )
set Switch to 0.375
elseif ( player->GetSpeed < 35 )
set Switch to 0.7
elseif ( player->GetSpeed < 65 )
set Switch to 0.5
elseif ( player->GetSpeed < 100 )
set Switch to 0.45
endif
set speed to "player"->GetSpeed
endif
endif ;end StandingPC == 1

end

_________________
THEO
Post Sat Jun 11, 2005 3:26 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Yes, this script should work, so long as I typed it correctly from my printout.

CollidingPC doesn't work because the water and bc_scum meshes don't have collision detection, though StandingPC seems to work fine.

And whether or not every variable I defined is actually in practical use any more within the script is beyond my knowledge, because I tested and changed and debugged the damn thing so many times.

Its nice to have some good feedback, but actually, I wish someone would try it out. Posting comments about the script before one even uses it is helpful, but the thing is, this script was distracting me from what I was working on, so I decided to hand it over to the forum, and let anyone and everyone fine detail it.

In other words, don't tell me how it would be better. Make it better, I know its possible (Theo has the right idea/spirit/hair plugs).

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Tue Jun 14, 2005 8:55 pm Send private message             Reply with quote                   up  
Theo
Developer Emeritus
16 Dec 2004

Location: PRAGUE

Now I really do not undersand? Did you tested the script already? Did it work?
If yes then I have only to say Good Job! I can see no way how could this script be radically optimalized.
If it didn't work as you imagined, try my version.
I cannot test it yet, because I lack CS here.
However this looks like clever script to me and see no reason why it should not work.

_________________
THEO
Post Tue Jun 14, 2005 9:05 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Okay...

1. The script does work. When you walk, it makes water splashing sounds.

2. The script is NOT optimized. I got so frustrated with it trying to make it work that I'd be suprised if there weren't more than a few unnessary things that its doing. What, I don't know.

3. There is a slight problem. The sounds tend to play one, then the other, regardless of whether or not you are actually moving when the other is played. (ie sometimes right after you stop, you'll hear an extra splash)

4. There is no sound for jumping into the water. There is a sound when you jump into normal water.

5. Like I said, this was distracting me from my claim, and I decided to allow others to optimize it, and fix anything that could be done better.

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Tue Jun 14, 2005 9:33 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Hmm? Nobody's going to give it a shot? No comments, even? How sad. Crying or Very sad I suppose I will work on this some time, then.
_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Fri Jul 15, 2005 4:47 pm Send private message             Reply with quote                   up  
Zalzidrax
Developer
03 Dec 2003

Location: Bothell, WA

For the splash you could check if getstandingPC goes from 0 to 1, via another variable.
Post Fri Jul 15, 2005 6:04 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Hehehe...

While attempting to completely redo this script, I ran across an idea that may everything much easier, and it's WAAAY more accurate...

Code:
begin TR_Po_WaterSoundV3

short InAir       ;for jumping

;for waterwalking:
float Zpos
float Dist
short once

if ( once == 0 )
   ;waterwalking box gets positioned at 29 units below this number
   set Zpos to GetPos, Z
   set once to 1
endif

set Dist to GetDistance, player

;loop the environmental sound
if ( GetSoundPlaying "Water Layer" == 0 )
   PlayLoopSound3DVP "Water Layer", 1.0, 1.0
endif

;for jumping outside of water
if ( GetPCJumping == 1 )
   set InAir to 1
endif

if ( GetStandingPC == 1 )
   
;landing in water
   if ( InAir == 1 )
      if ( player->GetSoundPlaying, "DefaultLand" == 1 )
         player->StopSound, "DefaultLand"
         player->PlaySound, "DefaultLandWater"
         set InAir to 0
      endif
   ;else
      ;jumping in water
      ;if ( GetPCJumping == 1 )
      ;   player->PlaySound, "DefaultLandWater"
      ;   set InAir to 1
      ;endif
   endif

;left foot

   if ( player->GetSoundPlaying, "FootBareLeft" == 1 )
      player->StopSound, "FootBareLeft"
      player->PlaySound "FootWaterLeft"
   endif
   if ( GetSoundPlaying, "FootHeavyLeft" == 1 )
      player->StopSound, "FootHeavyLeft"
      player->PlaySound "FootWaterLeft"
   endif
   if ( GetSoundPlaying, "FootMedLeft" == 1 )
      player->StopSound, "FootMedLeft"
      player->PlaySound "FootWaterLeft"
   endif
   if ( GetSoundPlaying, "FootLightLeft" == 1 )
      player->StopSound, "FootLightLeft"
      player->PlaySound "FootWaterLeft"
   endif

;right foot

   if ( player->GetSoundPlaying, "FootBareRight" == 1 )
      player->StopSound, "FootBareRight"
      player->PlaySound "FootWaterRight"
   endif
   if ( GetSoundPlaying, "FootHeavyRight" == 1 )
      player->StopSound, "FootHeavyRight"
      player->PlaySound "FootWaterRight"
   endif
   if ( GetSoundPlaying, "FootMedRight" == 1 )
      player->StopSound, "FootMedRight"
      player->PlaySound "FootWaterRight"
   endif
   if ( GetSoundPlaying, "FootLightRight" == 1 )
      player->StopSound, "FootLightRight"
      player->PlaySound "FootWaterRight"      
   endif

elseif ( InAir == 1 )
   ;reset InAir if landed on solid ground
   if ( player->GetSoundPlaying, "DefaultLand" )
      set InAir to 0
   endif
endif


end


For those that are too lazy to read the code, it finds out if the player is walking based upon the sound, stops that sound, then plays the water stepping sound. Works with Jumping in the water, too.
Just attach this script to terrain_bc_scum, or, if you have some of the non-scummy water, attach it to an editor marker box (the ones with collision) and place them underneath the water. WORT!!!


The only problems now are getting the "environmental" sound of the water to play (Water Layer) and water walking. Razz

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Fri Aug 19, 2005 4:55 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

No replies...

Anyways, I don't suppose anyone has thought of a good way to fix the water walking dilemma? The only possible solutions that I've thought of aren't very feasible, as one way would give "waterwalking" to any creature or character, and the other would require a lot of unique objects to run accurately.

Also, the "Water Layer" sound just isn't working for me, and I have no clue about fixing it either.

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Mon Sep 05, 2005 5:50 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

Well I'll move this to scripting forum to see if it gets looked at more. Very good job so far but I haven't unpacked my cs cd once again (I've moved again so it's not the same move :/)
At any rate the script "looks" good but I can't check out the problems without trying it in game to see what you mean.
Post Tue Sep 06, 2005 9:15 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Actually, there's nothing inherently wrong with this script (the latest). It plays the sounds when the water splashing sounds are meant to be played. It can be directly attached to terrain_bc_scum (if converted to an activator and the collision plane underneath it is above ground level), or to an editor marker box, used to blanket all the land beneath the water meshes.

I was simply trying to finish it up, such that there's no real difference between non-0 height water and TR's above 0 height water (aside from swimming in it), and make water walking and the environmental sound of water work somehow...

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Tue Sep 06, 2005 9:28 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

Well for the waterwalk you could either have the collision cast levitate or a really strong slow fall if you have waterwalk on you? Environmental sound and the blue color of water filling your screen I don't know (nor swimming or breath for that matter).
Post Tue Sep 06, 2005 11:23 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

No, casting levitate or slowfall on the player won't work for waterwalking.

Levitate would allow the player to fly above the water, and still go below it.

Slowfall would only slow the player from going into the water if they jumped, and I hope I don't have to explain why there's all kinds of problems with that.

As far as swimming goes, I've pretty much decided that's impossible.

The best solution that I've come up with is for an invisible collision box to somehow raise up from beneath the player if he's in the water when he casts, or simply be placed at the water's height if he's out of it, after which it follows the player around on the x and y axises...

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Tue Sep 06, 2005 11:58 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

Well I figured if the water was a droppoff the slow fall would work (It does work if you fall right) however all edges of the water would have to be dropoffs. As for the levitate you could end it when collision was over it's effect so flying wouldn't happen however I can't think of a way to stop the player from going under water.
Post Wed Sep 07, 2005 4:22 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Assassinace wrote:
Well I figured if the water was a droppoff the slow fall would work (It does work if you fall right) however all edges of the water would have to be dropoffs. As for the levitate you could end it when collision was over it's effect so flying wouldn't happen however I can't think of a way to stop the player from going under water.


No and no. I'm afraid that, in all likely-hood, the player probably won't 'fall right' and who would want to visit these bodies of water if they all looked the same (dropoffs all around)? As far as levitation goes, that entire idea entails all kinds of problems (what if the player goes from raised water to non-raised water?, Why does casting WaterWalk give the player Levitation [shows up as a spell that is active on them]?, etc...) and I would much rather find a more feasible, and less problematic, solution.

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Wed Sep 07, 2005 5:26 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

umm for the levitate I was thinking more when step into the fake water (enter the collision detection)it checks if you have waterwalk active and if you do casts a 1 sec levitate on you. repeat check every second. And I doubt either are worth while to add just options I was tossing out there.
Post Wed Sep 07, 2005 6:26 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Ah, alright. But collision detection, as far as I know, means that the player is colliding with an object, meaning unable to pass through it. If you can't see gray lines on the object when you push F4 in the CS, then you can walk through it, and you can't detect collision in a script. That's why this script can be attached to bc scum (there's a collision plain beneath it) and why it has to be attached to an editor marker box for other water (no collision plain on them).

And I don't mean to sound unappreciative of the feedback and ideas, because it is nice to have someone else thinking about this.

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Wed Sep 07, 2005 9:34 pm Send private message             Reply with quote                   up  
Odowacar

09 Sep 2005

Location: Finland

Cool script. I know nothing about scripting but this, I think, could be used in many places. Like when the player is walking through bushes in Black Marsh there is a proper sound. It could create a cool illusion of a real jungle.
_________________
Kun harakka hyppii hangella maassa on lunta
Post Thu Sep 15, 2005 7:51 pm Send private message       Send e-mail       Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Indeed, I agree, which is why I made it.

However, I wouldn't mind if someone else took over the water walking aspect and making the "Water Layer" sound actually play (or perhaps this script could be left alone, and those be completely different scipt(s)?), as I've been too busy with detailing Map 1, and figuring out some class-related woes.

Anyone who wants to try this out, though, and has downloaded 6-8-Dres, can load up that claim in Morrowind, open up the console, and type coc "W"

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Thu Sep 15, 2005 8:52 pm Send private message             Reply with quote                   up  
Sload
Developer Emeritus
06 Feb 2005



PoHa, tell me, is there any form of modding you can't do?
_________________
This is not my life
Post Fri Sep 16, 2005 1:15 am Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Uhm...

Well, I currently don't have a mic, so I guess I can't make sound... but I used to...

(copy+paste)(ignore strange url link to batty site, which I have no affiliation with):

http://www.freewebs.com/poha!/HomePage.swf


(Website that I never really pursued)

[Edit] Why don't the url tags work, all of a sudden? [/Edit]
[Edit] Probably because it doesn't end in .htm, eh?[/Edit]

I've done pretty much everything else that a person can do to mod the game, though.

Surely other people around here do a wide variety of things too? Or am I just some crazy ultra modder psychopath with too much time on his hands and yet, somehow, too little time on his hands?

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter


Last edited by PoHa! on Wed Sep 21, 2005 5:27 pm; edited 6 times in total
Post Fri Sep 16, 2005 4:57 am Send private message             Reply with quote                   up  
Zalzidrax
Developer
03 Dec 2003

Location: Bothell, WA

Naw, you're not crazy. Just because my work for TR has been primarily exteriors and a few interiors doesn't mean that I can't do other things. I just ahven't done themm for TR yet. My time right now is pretty much allocated to schoolwork though.
Post Sat Sep 17, 2005 5:54 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Well... that's good to know.

Given that this script has no problems in and of itself, (that I've been able to find, at least) and water walking may or may not be possible, what becomes of it now?

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Tue Sep 20, 2005 7:53 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

I think it goes with the water to objects of tamrial. Also if it is the final version I can post it in the finished scripts section.
Post Wed Sep 21, 2005 4:04 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Posting final, with unused portions removed:

Code:
begin TR_Po_WaterSoundV4

;This script makes the sound of walking in water provided the PC is standing
;     on an object that this script is attached to.
; Uses no outside variables.
; Should be attached to terrain_bc_scum* (as an activator) and an editor marker box.
; Cannot be attached to TR_water_* because they do not have any form of collision detection,
;     and thus cannot detect if the PC is standing on it. Editor Marker Boxes must be placed
;     at ground level beneath the water instead.

short InAir       ;for jumping

;for jumping outside of water
if ( GetPCJumping == 1 )
   set InAir to 1
endif

if ( GetStandingPC == 1 )
   
;landing in water
   if ( InAir == 1 )
      if ( player->GetSoundPlaying, "DefaultLand" == 1 )
         player->StopSound, "DefaultLand"
         player->PlaySound, "DefaultLandWater"
         set InAir to 0
      endif
   endif

;left foot

   if ( player->GetSoundPlaying, "FootBareLeft" == 1 )
      player->StopSound, "FootBareLeft"
      player->PlaySound "FootWaterLeft"
   endif
   if ( GetSoundPlaying, "FootHeavyLeft" == 1 )
      player->StopSound, "FootHeavyLeft"
      player->PlaySound "FootWaterLeft"
   endif
   if ( GetSoundPlaying, "FootMedLeft" == 1 )
      player->StopSound, "FootMedLeft"
      player->PlaySound "FootWaterLeft"
   endif
   if ( GetSoundPlaying, "FootLightLeft" == 1 )
      player->StopSound, "FootLightLeft"
      player->PlaySound "FootWaterLeft"
   endif

;right foot

   if ( player->GetSoundPlaying, "FootBareRight" == 1 )
      player->StopSound, "FootBareRight"
      player->PlaySound "FootWaterRight"
   endif
   if ( GetSoundPlaying, "FootHeavyRight" == 1 )
      player->StopSound, "FootHeavyRight"
      player->PlaySound "FootWaterRight"
   endif
   if ( GetSoundPlaying, "FootMedRight" == 1 )
      player->StopSound, "FootMedRight"
      player->PlaySound "FootWaterRight"
   endif
   if ( GetSoundPlaying, "FootLightRight" == 1 )
      player->StopSound, "FootLightRight"
      player->PlaySound "FootWaterRight"      
   endif

elseif ( InAir == 1 )
   ;reset InAir if landed on solid ground
   if ( player->GetSoundPlaying, "DefaultLand" )
      set InAir to 0
   endif
endif


end



Further, though I would still rather there be a way to make water walking with TR_water work, I can't really place a real use for it, since this water must always be shallow enough that the player can stand upright in it (no swimming).

As far as the Water Layer sound goes, I can't figure out why its not working, but it can be attached to something else. Still, it bugs me that this simple code doesn't work:

Code:
;loop the environmental sound
if ( GetSoundPlaying "Water Layer" == 0 )
   PlayLoopSound3DVP "Water Layer", 1.0, 1.0
endif


Anyways, finished code, and happy days for everyone except me...


...and you.

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Wed Sep 21, 2005 6:38 pm Send private message             Reply with quote                   up  
Assassinace
Developer
21 Aug 2003

Location: Dreamland

Well for now I'll post what does work in the finished section and update if anyone figures out how to fix it. You may not be happy about it but still good job.
Post Thu Sep 22, 2005 3:23 pm Send private message             Reply with quote                   up  
PoHa!
Developer Emeritus
25 Mar 2005

Location: Tulsa, OK

Meh... I'm happy that what I originally set out to do works, and works well. The other stuff is just what I think still needs to be done.

Getting people to actually use this script, however, might be a completely different hassle in itself. How many people have used TR_Water* ? and how many are going to want to go back and place Editor Marker boxes below that water? That may be the real challenge, now.

_________________
"When you find out someone's sleeping with your wife, you want to kill the f***er"
~Prof. Gardner

"You wiki'd my girlfriend?"
~Dexter
Post Thu Sep 22, 2005 4:48 pm Send private message             Reply with quote                   up  
Display posts from previous:   
This forum is locked: you cannot post, reply to, or edit topics. This topic is locked: you cannot edit posts or make replies.

 
The content of this site is © by the Tamriel Rebuilt community. Morrowind, its expansions, and its content is © Bethesda Softworks.
Forums powered by phpBB © 2001, 2005 phpBB Group